globals [ depth         ;; measures the number of recursive calls
          max-depth     ;; holds the peak depth
          halt          ;; if set to 1, maze-building stops
          spacing       ;; the patch distance bewteen centers of maze corridors
          z-spacing     ;; 0 - spacing
          edge-vs-spacing-x
          edge-vs-spacing-y
          maze-edge-x   ;; like screen-edge for the maze
          maze-edge-y   ;; 
          blocks-x       ;; the number of maze-blocks across
          blocks-y       ;; the number of maze-blocks down
          first-x       ;; marks the lower left corner.
          first-y      ;; "" 
          room-count   ;; to total maze-blocks in the grid
          radius        ;; number of patches from the center patch.
          mark-color    ;; complements the gap-color. marks unused maze blocks
          tiles         ;; patches that are stepping points on the grid
          walkers
          path-width
                  ]
breeds [ghosts runners]
turtles-own [ stack breadcrumb-index backtrack]
patches-own [breadcrumb]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; MAZE RUNNING PROCEDURES   ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
to leave-breadcrumb ;;turtle procedure
    set breadcrumb-of patch-here breadcrumb-index
end

to finish
  ask runners [if breadcrumb-of patch-here = 1
  
  [die   user-message "Done!"]
  ]

end

to wall-follow ;; turtle procedure
  ask runners [
  ifelse right-left? = true

  [lt 90
  while [pcolor-of patch-ahead 1 = black] [rt 90]
  fd 1 stamp 97]
  [rt 90
  while [pcolor-of patch-ahead 1 = black] [lt 90]
  fd 1 stamp 97]
  ]
end

to tremaux ;;turtle procedure following Tremaux's algorithm
  ask runners [
    set heading downhill4 breadcrumb

    ;;if encountering already traversed path, backtrack
    set backtrack max-one-of neighbors4 with [breadcrumb < breadcrumb-of myself][breadcrumb]
    if (breadcrumb-of patch-ahead 1 > 0) and (backtrack != nobody)
    [set heading towards backtrack]
                          
    fd 1
    ;;update the patch    
    set breadcrumb-index breadcrumb-index + 1
    if breadcrumb-of patch-here = 0 [leave-breadcrumb]
    stamp 97
    
    
    ]
    finish
end


to pastexperience ;;runner procedure
  ask runners [
    set heading downhill4 breadcrumb

    ;;if approaching ghost, backtrack
    set backtrack max-one-of neighbors4 with [breadcrumb < breadcrumb-of myself][breadcrumb]
    if (any? ghosts in-radius-nowrap 5) or ((breadcrumb-of patch-ahead 1 > 0) and (backtrack != nobody))
    [set heading towards backtrack]

    fd 1
    ;;update the patch    
    set breadcrumb-index breadcrumb-index + 1
    if breadcrumb-of patch-here = 0 [leave-breadcrumb]
    stamp 97
    
    
    ]
    ask ghosts [ifelse any? runners in-radius-nowrap 12 [showturtle][hideturtle]]
    finish
end



to expert-opinion ;;turtle procedure following Tremaux's algorithm without recursion
  ask runners [
    set heading downhill4 breadcrumb
    fd 1
    ;;update the patch    
    set breadcrumb-index breadcrumb-index + 1
    if breadcrumb-of patch-here = 0 [leave-breadcrumb]
    stamp 97
    ]
    finish
end

to explore-random ;;turtle procedure
  ask runners [
  if count neighbors4 with [breadcrumb = 0] > 2 [rt random 4 * 90]  
  set backtrack random 2
  ifelse backtrack = 1

  [
  while [pcolor-of patch-ahead 1 = black] [rt 90]
]
  [
  while [pcolor-of patch-ahead 1 = black] [lt 90]

  ]

  fd 1 stamp 97
  ]

end


to flood-fill ;;turtle procedure
  ask runners [
    set color 97
    if count neighbors4 with [pcolor = white] > 1 [hatch 2 [set color 97]]
    set heading downhill4 breadcrumb
 
                          
    fd 1
    ;;update the patch    
    set breadcrumb-index breadcrumb-index + 1
    if breadcrumb-of patch-here = 0 [leave-breadcrumb]
    stamp 97
        ]

end


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; DRAWING PROCEDURES        ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
to draw-white
    if mouse-down?
    [      ask patch-at mouse-xcor mouse-ycor
        [ set pcolor white set breadcrumb 0]
    ]
end
to draw-black
    if mouse-down?
    [      ask patch-at mouse-xcor mouse-ycor
        [ set pcolor black set breadcrumb 100000]
    ]
end



;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; MAZE BUILDING PROCEDURES  ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


to push ; turt;e pushes current coords onto stack, before turning
    set stack fput ( list xcor ycor ) stack
end

to pop ; turtle pops previous turn point from stack
  locals [ xy ]
  set xy item 0 stack
  set stack but-first stack
  setxy (item 0 xy) (item 1 xy)
end

to setup
  clear-all
  set path-width 1
  ;; path-width is width of drawn maze path, in patches
  ;; radius should always work out to integer, but just in case...
  set radius int( ( path-width - 1 ) / 2 )
  set mark-color white
  
  ; spacing is distance 'tween centers of paths
  set spacing 1 + path-width
  ; zero minus spacing
  
  set tiles patches with
  [    pxcor mod spacing = 0
   and pycor mod spacing = 0
   and abs pxcor + radius + 1 < screen-edge-x
   and abs pycor + radius + 1 < screen-edge-y
  ]
 
  ; the total number of blocks in the maze
  set room-count count tiles
    
  mark-tiles

  set halt 0
  create-walkers  

end

to create-walkers
  set walkers 1
  if walkers >= 1 + room-count / 10
  [ set walkers 1 + room-count / 10 ]
  create-custom-turtles walkers
  [ pick-spot
    while [ any? other-turtles-here ]
    [ pick-spot ]
    set heading 0
    ifelse (perfect-maze? = true)
    [set color gray] [set color white]
    set heading 90 * random 4
    ask patches in-radius radius [ set pcolor color-of myself ]
    set stack []
    push
  ]

end
 
to pick-spot
    locals [ spot ]
    set spot tiles with [ not any? turtles-here ]
    ifelse any? spot
    [ set spot random-one-of spot
      set xcor pxcor-of spot
      set ycor pycor-of spot
    ]
    [ die ]
end

to mark-tiles
   ask tiles [ set pcolor mark-color ]
end


to build-maze ;; turtle procedure 
  locals [ paths target left-right straight curve? running my-color]

  if halt = 1 [ stop ]
  set depth depth + 1
  if depth > max-depth [ set max-depth depth ]
  
   ; make list of open directions to travel
   set paths find-open-paths
   ifelse not any? paths
   [ ifelse length stack > 0
     ; if there's no where to go, pop back to the location
     ; of the previous turn, and start again from there.
     [ pop ]
     [ stop ]
   ]
   [ ; there is somewhere to go, so...
     ; first, identify the patch that is straight ahead
     set straight patch-ahead spacing
     set left-right paths with [ self != straight ]
     ; check if I should go straight, or maybe curve?
     set curve? random-float 1.0 < curvyness
     ifelse ( curve? and any? left-right )
            or not is-open straight
     [ ; I should curve, or I can't go straight.
       ; so pick a direction, avoiding picking straight.
       set target random-one-of left-right
       ; mark the destination, to help prevent another
       ; turtle from trying to go there.
       set pcolor-of target color
       ; add my current location to the list of
       ; places where I made a turn. I come back
       ; here, later.
       push
       ; turn to the new location 
       set heading towards target
       ; go there!
       draw-move
     ]
     [ ; I'm supposed to go straight.
       ; so first I'll leave myself a note, so I
       ; remember that I'm going straight for a while.
       set running true
       ; While I'm running...
       while [ running ]
       [ ; mark my target patch
         set pcolor-of straight color
         ; turn to face it
         set heading towards straight
         ; go there!
         draw-move
         ; identify the next patch
         set straight patch-at ( dx * spacing) ( dy * spacing )
         ; Am I still running?
         ; if I pick a number more than the curvyness factor,
         ; and the patch ahead is clear, I'm still running!
         set running ( random-int-or-float 1.0 >= curvyness and is-open straight )
       ]
     ]
   ]
   if length stack = 0 [ stop ]
end


to-report find-open-paths
  locals [ paths path-list ]
  set paths (patches
              at-points
              (map [ (list (?1 * spacing ) (?2 * spacing) )] [ 0 0 1 -1 ] [ 1 -1 0 0 ])
             ) with [ pcolor = mark-color ]
  report paths
end


to draw-move
    locals [ my-color start-spot]
    set my-color color
    set start-spot patch-here
    ifelse radius > 0
    [ repeat spacing
      [ ask patches in-radius radius [ set pcolor my-color ] ; with [ pcolor != my-color ][ set pcolor my-color ]
        jump 1 ]
      ask patches in-radius radius [ set pcolor my-color ]
    ]
    [ repeat spacing 
      [ jump 1
        stamp color
      ]
    ]
    ask start-spot [ ask patches in-radius radius [ set pcolor my-color - 2 ] ]
 end


to-report is-open [ a-patch ]
    report (pcolor-of a-patch = mark-color)
end

    
to setup-and-go
    setup
    display
    go
    ask turtles [die]
    ask patches [if pcolor != black [set pcolor white]
                 ]
    ask patches with [pcolor = black][set breadcrumb 100000]
    ask patches with [pcolor = white][set breadcrumb 0]
    set-default-shape runners "circle"
    create-runners 1
    ask runners [bk screen-edge-y rt 90 
    fd screen-edge-x - 2 lt 90 set color red 
    set pcolor-of patch-ahead 1 white 
    set breadcrumb-of patch-ahead 1 0 
    set pcolor-of patch-here red
    set breadcrumb-of patch-here 1
    set breadcrumb-index 1
    ]

    set-default-shape ghosts "ghost"
    create-ghosts 2 
    ask ghosts [set color violet rt random 360 fd random screen-edge-x hideturtle]

end

to go
    ask turtles
    [ go-turtle
    ]
end

to go-turtle
    push 
    while [ length stack > 0 ]
    [ build-maze ]
end


@#$#@#$#@
GRAPHICS-WINDOW
196
10
554
389
14
14
12.0
1
10
1
1
1

CC-WINDOW
196
392
554
453
Command Center

SLIDER
10
217
150
250
curvyness
curvyness
0
1
0.8
0.1
1
NIL

BUTTON
10
68
162
101
BUILD A (new) MAZE
setup-and-go
NIL
1
T
OBSERVER
NIL

SWITCH
10
181
148
214
perfect-maze?
perfect-maze?
1
1
-1000

BUTTON
10
276
141
309
draw passage (white)
draw-white
T
1
T
OBSERVER
T

BUTTON
10
313
139
346
draw wall (black)
draw-black
T
1
T
OBSERVER
T

TEXTBOX
583
20
673
38
RUN THE MAZE

SWITCH
645
156
754
189
right-left?
right-left?
1
1
-1000

BUTTON
560
157
641
190
wall-follow
wall-follow
T
1
T
OBSERVER
T

BUTTON
562
270
696
303
monitor as you go
tremaux
T
1
T
OBSERVER
T

MONITOR
579
50
645
99
remaining
count patches with [pcolor = white]
0
1

TEXTBOX
12
255
102
273
EDIT THE MAZE

BUTTON
562
308
637
341
NIL
flood-fill
T
1
T
OBSERVER
T

BUTTON
561
233
672
266
expert opinion
expert-opinion
T
1
T
OBSERVER
T

BUTTON
560
120
692
153
explore at random
explore-random
T
1
T
OBSERVER
T

TEXTBOX
11
115
152
175
A perfect maze is one without loops. A braided maze contains loops.

TEXTBOX
665
51
755
111
THE MONITOR\nshows how you are doing.

BUTTON
561
195
682
228
past experience
pastexperience
T
1
T
OBSERVER
T

TEXTBOX
12
360
163
435
The slider at the top of the maze display controls the speed of the simulation.

TEXTBOX
10
9
157
53
To start, click the button below and choose your strategy on the right.

TEXTBOX
568
354
746
429
If a button is black, it is still on. Click it off before building a new maze. The command center at left is for experienced NetLogo users.

@#$#@#$#@
WHAT IS IT?
-----------
This model demonstrates a variety of maze-running strategies as they encounter a variety of randomly generated mazes. These strategies evoke and resemble human decision-making frameworks.

For simplicity, the mazes and the strategies are orthogonal -- the moves are at right angles, not diagonal. You can edit the mazes that are generated before your run them, using the DRAW PASSAGE and DRAW WALL buttons and using the mouse.

This model differs from real life in two ways:

1. We're asking you to run cheeseless mazes. Drawing on our life experiences, it is easy enough to imagine finding -- or missing -- the cheese. There are no monsters or ghosts, except in the Past Experience mode.

2. You can tell how you are doing. THE MONITOR (on the upper right) shows the number of unvisited squares. It's not ambiguous, and it doesn't lie.

The maze evokes life's possibilities and potentials. How well does your decision strategy or framework fulfill life's potential? How about that of your family, your organization, or your various governments?

THE STRATEGIES
-------------- 
EXPLORE AT RANDOM. This strategy is a common one in human affairs. The maze runner proceeds ahead until she arrives at a junction or turn, at which point a random path is taken.

WALL-FOLLOWER. This resembles an ideological or faith-based approach. The maze runner keeps a wall on his right (or left) at all times. You can stop and reverse the preference at any time using the "right-left?" switch. Wall-following works well in perfect mazes without chambers or loops. Try a non-perfect maze and see if you can explore all possibilities with a "pendulum" strategy, alternating right and left.

PAST EXPERIENCE. This strategy resembles the common human decision framework based on past experience, peer pressure, or on the stories we keep telling ourselves about our failures and successes (our beliefs). Some adaptation can occur: each time this strategy is run, a different theory of the maze is attempted. The purple ghosts you see represent the beliefs or fears of the maze-runner, and are not features of the maze itself.

EXPERT OPINION. This strategy resembles much expert opinion in that there is a definite method for seeking untrod passageways, as well as returning to the starting point. However, there is little effective monitoring, and some passages remain unseen.

MONITOR AS YOU GO. This maze-running strategy, an implementation of Tremaux's algorithm or rule, marks the passages that have been traversed, thus preventing the maze runner from traversing a passage twice in the same direction. Though it is effective and efficient for exhausting the possibilities of a fixed maze, if you stop the procedure during its run (click the black button) and add new passageways to what has already been run, the maze runner will not always find them.

FLOOD-FILL. This strategy resembles a paradigm shift or phase transition. It resembles decision making that simultaneously considers ecological, economic, and social factors for the short and long term, and includes everyone.



SOME RIGHTS RESERVED
--------------------
This model may be freely distributed, shared, and modified, provided sources are credited. Please credit James Steiner and the Managing Wholes models page:

http://managingwholes.com/models

The maze-creation portion of this model is based on a model by James P. Steiner.
This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike License. To view a copy of this license, visit 

http://creativecommons.org/licenses/by-nc-sa/1.0/

or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 151 152 137 77 105 67 89 67 66 74 48 85 36 100 24 116 14 134 0 151 15 167 22 182 40 206 58 220 82 226 105 226 134 222
Polygon -16777216 true false 151 150 149 128 149 114 155 98 178 80 197 80 217 81 233 95 242 117 246 141 247 151 245 177 234 195 218 207 206 211 184 211 161 204 151 189 148 171
Polygon -7566196 true true 246 151 241 119 240 96 250 81 261 78 275 87 282 103 277 115 287 121 299 150 286 180 277 189 283 197 281 210 270 222 256 222 243 212 242 192
Polygon -16777216 true false 115 70 129 74 128 223 114 224
Polygon -16777216 true false 89 67 74 71 74 224 89 225 89 67
Polygon -16777216 true false 43 91 31 106 31 195 45 211
Line -1 false 200 144 213 70
Line -1 false 213 70 213 45
Line -1 false 214 45 203 26
Line -1 false 204 26 185 22
Line -1 false 185 22 170 25
Line -1 false 169 26 159 37
Line -1 false 159 37 156 55
Line -1 false 157 55 199 143
Line -1 false 200 141 162 227
Line -1 false 162 227 163 241
Line -1 false 163 241 171 249
Line -1 false 171 249 190 254
Line -1 false 192 253 203 248
Line -1 false 205 249 218 235
Line -1 false 218 235 200 144

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

ghost
false
0
Circle -7566196 true true 61 30 179
Rectangle -7566196 true true 60 120 240 232
Polygon -7566196 true true 60 229 60 284 105 239 149 284 195 240 239 285 239 228 60 229 60 229 60 229
Circle -1 true false 81 78 56
Circle -16777216 true false 99 98 19
Circle -1 true false 155 80 56
Circle -16777216 true false 171 98 17

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@